プロセスの取得方法を説明します。

System.Diagnostics.Processクラスを使用します。

自分自身のプロセスを取得する

Dim hPros As System.Diagnostics.Process = System.Diagnostics.Process.GetCurrentProcess()

'プロセス名を表示する
MessageBox.Show(hPros.ProcessName)

hPros.Close()
hPros.Dispose()

実行中の全てのプロセスを取得する

Dim hPros As System.Diagnostics.Process() = System.Diagnostics.Process.GetProcesses()

'コンピュータ名を指定すると、別のコンピュータのプロセスが取得可能です
'hPros = System.Diagnostics.Process.GetProcesses("MachineName")

Dim str As String = ""

'取得できたプロセスからプロセス名を取得する
For Each hp As System.Diagnostics.Process In hPros
    str &= hp.ProcessName & System.Environment.NewLine
Next

'実行中のすべてのプロセス名を表示する
MessageBox.Show(str)

コンピュータ名を指定することで、別のコンピュータのプロセスが取得可能になります。
hPros = System.Diagnostics.Process.GetProcesses(“xxxxxxxxxx”)

指定した名前に合致するプロセスを全て取得する

System.Diagnostics.ProcessクラスのGetProcessesByNameメソッドを使用します。

Dim hPros As System.Diagnostics.Process() = System.Diagnostics.Process.GetProcessesByName("Notepad")

Dim str As String = ""

'取得できたプロセスからプロセスIDを取得する
For Each hp As System.Diagnostics.Process In hPros
    str &= hp.id & System.Environment.NewLine
Next

'取得したっ全てのプロセスIDを表示する
MessageBox.Show(str)

指定したIDに合致するプロセスを取得する

System.Diagnostics.ProcessクラスのGetProcessByIdメソッドを使用します。

'プロセスIDが0のプロセスを取得する
Dim hPros As System.Diagnostics.Process = System.Diagnostics.Process.GetProcessById(0)

'取得できたプロセス名を表示する
If Not hPros Is Nothing Then
    MessageBox.Show(hPros.ProcessName)
End If

hPros.Close()
hPros.Dispose()

 

 

アプリケーションが終了したかどうかを判断する

System.Diagnostics.Processクラスで起動したプログラムを、呼び出し側で終了したか確認する方法を説明します。
プロセスのインスタンスの、HasExitedプロパティを使用します。
HasExitedプロパティは、プログラムが終了している場合はTrueです。

HasExitedプロパティによる判断

'アプリケーションを起動して、Processのインスタンスを取得する
Dim hPros As System.Diagnostics.Process = System.Diagnostics.Process.Start("Notepad")

'５秒ほど待機する(この間に起動したアプリケーションを終了させてください)
System.Threading.Thread.Sleep(5000)

'起動したプログラムが終了したかどうかを判断する
If hPros.HasExited Then
    MessageBox.Show("終了しています")
Else
    MessageBox.Show("終了していません")
End If

'不要になった時点で破棄する
hPros.Close()
hPros.Dispose()

 

アプリケーションが終了したことをイベントで通知する

System.Diagnostics.Processクラスで起動したプログラムを、呼び出し側で終了をイベントで確認する方法を説明します。
プロセスのインスタンスの、EnableRaisingEventsプロパティを使用します。
EnableRaisingEventsプロパティを Trueにし追加したイベントを呼び出します。

イベントハンドラによる終了判断

'アプリケーションを起動して、Processのインスタンスを取得する
Dim hPros As System.Diagnostics.Process = System.Diagnostics.Process.Start("Notepad")

' このプログラムが終了した時に Exited イベントを発生させる
hPros.EnableRaisingEvents = True

'Exited イベントハンドラを追加する
AddHandler hPros.Exited, AddressOf Prog_Exited

'アプリケーションが終了したことを通知するイベント
Private Sub Prog_Exited(ByVal sender As Object, ByVal e As System.EventArgs)
    MessageBox.Show("終了しました")
End Sub