Back to Top

プログラムの覚書

Category: スレッド・タスク

VB.NET Taskクラスの処理待ちの方法

Taskクラスを使用して非同期処理をする際、同期をとるためのタスク待ちについて記載します。

ここでは、非同期の処理待ちをする事ができる Async & AWait  と Wait()メソッドを説明します。

プログラムを起動したときのメインタスクは、UIタスク(ユーザインターフェースタスク)で、Taskクラスで起動するタスクは、ローカルタスクと以下記載します。

Async と AWait でのタスク待ち

GUIでボタンを押して重たい処理する場合を例にします。

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    System.Threading.Thread.Sleep(10000)     '重たい処理
End Sub

以上の処理を実行すると、処理が終了するまで、フォーム移動などの操作が出来なくなります。

次にTaskクラスを使用して処理を実行します。

Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    DirectCast(sender, Button).Enabled = False        'ボタンを選択できないようにする

    Dim task As Task = Task.Run(
        Sub()
            System.Threading.Thread.Sleep(10000)      '重たい処理
        End Sub
    )
    Await task                                        '処理が完了するのを非同期的に待つ

    MessageBox.Show("Task End")

    DirectCast(sender, Button).Enabled = True
End Sub

Async & Await の非同期メソッドで、UIスレッドに同期的な継続処理に自動変換されます。

上記では、ローカルタスクで処理が実行されるので、ボタンの選択は処理が終わるまで出来ませんが、フォームの操作は出来ます。

Await で処理を止めているのではなく、非同期的に待っているので、UIタスクに処理を戻します。

ローカルタスクでの処理が終了したら、MessageBox.Show(“Task End”)が実行されます。

上記のコードの省略化

Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    DirectCast(sender, Button).Enabled = False        'ボタンを選択できないようにする

    Await Task.Run(
        Sub()
            System.Threading.Thread.Sleep(10000)      '重たい処理
        End Sub
    )
    MessageBox.Show("Task End")

    DirectCast(sender, Button).Enabled = True
End Sub

戻り値がある場合

Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    DirectCast(sender, Button).Enabled = False        'ボタンを選択できないようにする

    Dim result As Boolean = Await Task.Run(
        Function() As Boolean
            System.Threading.Thread.Sleep(5000)
            Return True
        End Function
    )
    MessageBox.Show("Task End")

    DirectCast(sender, Button).Enabled = True
End Sub

・Task.Run()の場合は、Task(Of)の戻り値になります。

・Await Task.Run()の場合は、指定した戻り値になります。

 

Waitメソッドでの処理待ち

GUIで Wait() メソッドを使用することは、通常ありません。

以下のようにCUIの時、Awaitをおこなっても処理が終了しまう場合、に使用します。

Imports System.Threading

Module Module1

    Sub Main()
        Dim task As Task = Task.Run(
            Sub()
                System.Threading.Thread.Sleep(5000)      '重たい処理
                Console.WriteLine("Task End")
            End Sub
        )
        task.Wait()

        Console.WriteLine("End")
    End Sub

End Module

 

VB.NET Taskクラス基本的な起動

Taskクラスを使用して、非同期処理を実行する場合、タスクの起動方法には、数通りの起動方法があります。

ここでは、タスクの起動方法について記載します。

Taskクラスは、NET Framework 4.0から使用できます。

・System.Threadingをインポートします。

戻り値の無いタスクの起動

Task.Start()を使用する方法

Dim task As Task = New Task(                   'タスクの作成
    Sub()
        System.Threading.Thread.Sleep(5000)    '重たい処理
    End Sub
)
task.Start()                                   'タスク開始

Task.Factory.StartNew()を使用する方法

Dim task As Task = Task.Factory.StartNew(      'タスクを作成してタスクを起動
    Sub()
        System.Threading.Thread.Sleep(5000)    '重たい処理
    End Sub
)

Task.Run()を使用する方法

Dim task As Task = Task.Run(                   'タスクを作成してタスクを起動
    Sub()
        System.Threading.Thread.Sleep(5000)    '重たい処理
    End Sub
)

Task.Run()は、.NET Framework4.5 から使用できます。
 

戻り値のあるタスクの起動

戻り値のあるタスクは、Task(Of TResult)の型を使用します。

以下の例は、Integer型の値を返すTask(Of Integer)です。

Task.Start()を使用する方法

Dim result As Task(Of Integer) = New Task(
    Function() As Integer
        System.Threading.Thread.Sleep(5000)     '重たい処理
        Return 1
    End Function
)
result.Start()                                  'タスク起動

Task.Factory.StartNew()を使用する方法

Dim result As Task(Of Integer) = Task.Factory.StartNew(
    Function() As Integer
        System.Threading.Thread.Sleep(5000)    '重たい処理
        Return 1
    End Function
)

Task.Ran()を使用する方法

Dim result As Task(Of Integer) = Task.Run(
    Function() As Integer
        System.Threading.Thread.Sleep(5000)    '重たい処理
        Return 1
    End Function
)

 

引数のあるタスクの起動

タスクで呼び出す関数クラスの例

Public Class TaskActionClass
    '引数のある関数
    Public Sub Action1(count As Integer)
        For i As Integer = 0 To count
            System.Threading.Thread.Sleep(1000)
        Next
    End Sub

    '引数と戻り値のある関数
    Public Function Action2(count As Integer) As Integer
        For i As Integer = 0 To count
            System.Threading.Thread.Sleep(1000)
        Next
        Return count
    End Function
End Class

戻り値なし・引数あり 関数をタスク起動

Dim act1 = New TaskActionClass()

Dim t As Task = Task.Run(Sub() act1.Action1(5))
'または
Dim t As Task = New Task(AddressOf act1.Action1, 5)
t.Start()

戻り値あり・引数あり 関数をタスク起動

Dim act1 = New TaskActionClass()

Dim t = Task.Run(Function() act1.Action2(5))
'また厳密には
Dim t As Task(Of Integer) = Task.Run(Function() act1.Action2(5))

 

※タスクの起動のコーディングには、いろいろな方法があります。NET Frameworkのバージョンによっても異なりますので、状況に合わせて使用してください。